pragma solidity ^0.4.18;

interface token {
    function transfer(address receiver, uint amount) public;
}

contract Crowdsale {
    address public beneficiary;  // 募资成功后的收款方
    uint public fundingGoal;     // 众筹目标，单位是ether
    uint public amountRaised;    // 已筹集金额数量， 单位是wei
    uint public deadline;        // 募资截止期
    
    uint public price;           // token与以太坊的汇率, token卖多少钱
    token public tokenReward;    // 要卖的token
    uint8 public decimals = 18;
    
    mapping(address => uint256) public balanceOf; //保存众筹地址
    
    bool fundingGoalReached = false;  // 众筹是否达到目标
    bool crowdsaleClosed = false;   //  众筹是否结束
   
    //记录已接收的ether通知
    event GoalReached(address recipient, uint totalAmountRaised);
    
    //转帐通知
    event FundTransfer(address backer, uint amount, bool isContribution);
    
    /**
     * 构造函数, 设置相关属性
     */
    function Crowdsale(
        address ifSuccessfulSendTo,
        uint fundingGoalInEthers,
        uint durationInMinutes,
        uint finneyCostOfEachToken,
        address addressOfTokenUsedAsReward) public {
            beneficiary = ifSuccessfulSendTo;
            fundingGoal = fundingGoalInEthers * 1 ether;
            deadline = now + durationInMinutes * 1 minutes;
            price = finneyCostOfEachToken * 1 finney;
            tokenReward = token(addressOfTokenUsedAsReward);   // 传入已发布的 token 合约的地址来创建实例
    }
    
    /**
     * 无函数名的Fallback函数，
     * 
     * 在向合约转账时，这个函数会被调用
     */
    function () payable public {
        require(!crowdsaleClosed);
        uint amount = msg.value;
        
        // 捐款人的金额累加
        balanceOf[msg.sender] += amount;
        
        // 捐款总额累加
        amountRaised += amount;
        
        tokenReward.transfer(msg.sender, amount / price * 10 ** uint256(decimals));
        FundTransfer(msg.sender, amount, true);
    }
    
    /**
    * 定义函数修改器modifier（作用和Python的装饰器很相似）
    * 用于在函数执行前检查某种前置条件（判断通过之后才会继续执行该方法）
    * _ 表示继续执行之后的代码
    */
    modifier afterDeadline() { if (now >= deadline) _; }
    
    /**
     * 判断众筹是否完成融资目标， 这个方法使用了afterDeadline函数修改器
     */
    function checkGoalReached() afterDeadline public {
        if (amountRaised >= fundingGoal) {
            // 达成众筹目标
            fundingGoalReached = true;
            GoalReached(beneficiary, amountRaised);
        }
        crowdsaleClosed = true;
    }
    
    /**
     * 完成融资目标时，融资款发送到收款方
     * 未完成融资目标时，执行退款
     */
    function safeWithdrawal() afterDeadline public {
        // 如果没有达成众筹目标
        if (!fundingGoalReached) {
            // 获取合约调用者已捐款余额
            uint amount = balanceOf[msg.sender];
            balanceOf[msg.sender] = 0;
            if (amount > 0) {
                if (msg.sender.send(amount)) {
                    FundTransfer(msg.sender, amount, false);
                } else {
                    balanceOf[msg.sender] = amount;
                }
            }
        }
        
        // 如果达成众筹目标，并且合约调用者是受益人
        if (fundingGoalReached && beneficiary == msg.sender) {
            if (beneficiary.send(amountRaised)) {
                FundTransfer(beneficiary, amountRaised, false);
            } else {
                // If we fail to send the funds to beneficiary, unlock funders balance
                fundingGoalReached = false;
            }
        }
    }
}